# Install DNS server.
#
class dns::server {

    case $operatingsystem {
        centos,fedora: {
            $rootdir = "/var/named/chroot"
            package { "bind":
                name   => "bind-chroot",
                ensure => installed,
            }
        }
        default: {
            $rootdir = "/var/named"
        }
    }

    file { "${rootdir}/etc/rndc.key":
        ensure  => present,
        mode    => 0640,
        owner   => root,
        group   => named,
        require => $operatingsystem ? {
            openbsd => undef,
            default => Package["bind"],
        },
    }
    exec { "rndc-confgen":
        command => "rndc-confgen -a -t ${rootdir}",
        path    => "/bin:/usr/bin:/sbin:/usr/sbin",
        unless  => "test -s ${rootdir}/etc/rndc.key",
        require => File["${rootdir}/etc/rndc.key"],
    }
    file { "/etc/rndc.key":
        ensure  => "${rootdir}/etc/rndc.key",
        owner   => root,
        group   => $operatingsystem ? {
            openbsd => wheel,
            default => root,
        },
        require => Exec["rndc-confgen"],
        notify  => Service["named"],
        seltype => "dnssec_t",
    }

    service { "named":
        ensure  => running,
        enable  => true,
        status  => "/usr/sbin/rndc status",
        stop    => $operatingsystem ? {
            openbsd => "pkill -u named",
            default => undef,
        },
        start   => $operatingsystem ? {
            openbsd => "/usr/sbin/named",
            default => undef,
        },
        require => Exec["rndc-confgen"],
    }

    file { "${rootdir}/etc/named.conf":
        ensure  => present,
        source  => [ "puppet:///files/dns/named.conf.${fqdn}",
                     "puppet:///files/dns/named.conf", ],
        mode    => 0640,
        owner   => root,
        group   => named,
        require => $operatingsystem ? {
            openbsd => undef,
            default => Package["bind"],
        },
        notify  => Service["named"],
    }

}


# Install dynamic DNS update script
#
# === Global variables
#
#   $dns_nsupdate_name:
#       FQDN to update into DNS.
#
#   $dns_nsupdate_key:
#       DNS key to use when updating entry. Usually in format:
#         <keyname> <secret>
#       for example:
#         gw1.example.com. sZ6GgTZLBX83LXCoo
#
#   $dns_nsupdate_server:
#       DNS server address where to update entry.
#
#   $dns_nsupdate_zone:
#       Zone name to update. Defaults to domain part of
#       $dns_nsupdate_name variable.
#
class dns::nsupdate {

    file { "/usr/local/sbin/nsupdate.sh":
        ensure  => present,
        content => template("dns/nsupdate.sh.erb"),
        mode    => 0700,
        owner   => root,
        group   => $operatingsystem ? {
            openbsd => wheel,
            default => root,
        },
    }

    cron { "nsupdate":
        ensure  => present,
        command => "/usr/local/sbin/nsupdate.sh",
        minute  => "*/5",
        require => File["/usr/local/sbin/nsupdate.sh"],
    }
      
}