From c0b4da45474e49e2b5eae0fa1dca44ae665a67e6 Mon Sep 17 00:00:00 2001
From: Ossi Salmi <osalmi@iki.fi>
Date: Sat, 29 Jun 2013 23:27:29 +0300
Subject: [PATCH] Initial version of redis module

---
 redis/manifests/init.pp        | 66 ++++++++++++++++++++++++++++++++++
 redis/templates/local.conf.erb |  6 ++++
 2 files changed, 72 insertions(+)
 create mode 100644 redis/manifests/init.pp
 create mode 100644 redis/templates/local.conf.erb

diff --git a/redis/manifests/init.pp b/redis/manifests/init.pp
new file mode 100644
index 0000000..a43866d
--- /dev/null
+++ b/redis/manifests/init.pp
@@ -0,0 +1,66 @@
+# Install Redis.
+#
+# === Parameters
+#
+#   $datadir:
+#       Directory for redis database dumps.
+#       Defaults to "/srv/redis".
+#
+#   $password:
+#       Optional password for client connections.
+#
+class redis($datadir="", $password="") {
+
+    package { "redis":
+        ensure => installed,
+    }
+
+    if $datadir {
+        file { $datadir:
+            ensure  => directory,
+            mode    => "0700",
+            owner   => "redis",
+            group   => "redis",
+            before  => File["/srv/redis"],
+            require => Package["redis"],
+        }
+        file { "/srv/redis":
+            ensure  => link,
+            target  => $datadir,
+            before  => Service["redis"],
+        }
+    } else {
+        file { "/srv/redis":
+            ensure  => directory,
+            mode    => "0700",
+            owner   => "redis",
+            group   => "redis",
+            before  => Service["redis"],
+            require => Package["redis"],
+        }
+    }
+
+    augeas { "set-redis-include":
+        changes => "set include /etc/redis.local.conf",
+        incl    => "/etc/redis.conf",
+        lens    => "Spacevars.simple_lns",
+        notify  => Service["redis"],
+        require => Package["redis"],
+    }
+
+    file { "/etc/redis.local.conf":
+        ensure  => present,
+        mode    => "0600",
+        owner   => "redis",
+        group   => "redis",
+        content => template("redis/local.conf.erb"),
+        require => Package["redis"],
+        notify  => Service["redis"],
+    }
+
+    service { "redis":
+        ensure => running,
+        enable => true,
+    }
+
+}
diff --git a/redis/templates/local.conf.erb b/redis/templates/local.conf.erb
new file mode 100644
index 0000000..0265b19
--- /dev/null
+++ b/redis/templates/local.conf.erb
@@ -0,0 +1,6 @@
+bind 127.0.0.1
+dir /srv/redis
+appendonly yes
+<% if @password -%>
+requirepass <%= @password %>
+<% end -%>